SetPlayerFightingStyle

Описание:

Устанавливает вторичный стиль боя игрока.

Параметры:

(playerid, style)

playerid

ID игрока.

style

Стиль боя.

Возвращаемое значение:

1, если указан один из правильных ID стиля боя, иначе 0.

Примечание

Функция устанавливает только вторичный стиль боя, основной набор ударов остаётся без изменений. Чтобы использовать удары из вторичного набора, следует зажать кнопку прицела и нажать клавишу действия (по умолчанию ПКМ/Caps Lock и F/Enter соответственно).

Баг SA-MP

Возвращаемое значение зависит только от правильности ID стиля боя. Если игрок не подключен, функция всё равно может вернуть 1.

Пример использования:

enum e_FightingStyleInfo
{
    fsID,
    fsName[13]
};
static const fighting_style_info[][e_FightingStyleInfo] =
{
    { FIGHT_STYLE_NORMAL, "Обычный" },
    { FIGHT_STYLE_BOXING, "Бокс" },
    { FIGHT_STYLE_KUNGFU, "Кунг-фу" },
    { FIGHT_STYLE_KNEEHEAD, "Без правил" },
    { FIGHT_STYLE_GRABKICK, "Grabkick" },
    { FIGHT_STYLE_ELBOW, "Удары локтём" }
};

CMD:setfstyle(playerid, params[])
{
    if (PlayerInfo[playerid][pAdmin] == ADM_NONE)
        return SendClientMessage(playerid, -1, "Вы не администратор сервера!");
    extract params -> new player:targetid, style; else // sscanf2
        return SendClientMessage(playerid, -1,
            "Использование: /setfstyle [ID игрока/часть ника] [ID стиля (1-6)]");
    if (style < 1 || style > 6)
        return SendClientMessage(playerid, -1, "Ошибка: ID стиля боя должен быть от 1 до 6.");
    --style;
    SetPlayerFightingStyle(targetid, fighting_style_info[style][fsID]);
    new string[128];
    GetPlayerName(targetid, string, sizeof(string));
    format(
        string, sizeof(string), "Вы установили игроку %s стиль боя \"%s\".",
        string, fighting_style_info[style][fsName]
    );
    return SendClientMessage(playerid, -1, string);
}

См. также:

• GetPlayerFightingStyle