IsPlayerInVehicle

Описание:

Проверяет игрока на нахождение в указанном транспортном средстве.

Параметры:

(playerid, vehicleid)

playerid

ID игрока.

vehicleid

ID транспортного средства.

Возвращаемое значение:

1, если игрок находится в указанном т/с (за рулём или на пассажирском месте), иначе 0.

Пример использования:

const VEHICLE_MODEL_INFERNUS = 411;
const VEHICLE_COLOR_BLUE = 152;
new boost_veh;

public OnGameModeInit()
{
    boost_veh = CreateVehicle(
        VEHICLE_MODEL_INFERNUS, 2500.0, -1658.0, 13.25, 90.0,
        VEHICLE_COLOR_BLUE, VEHICLE_COLOR_BLUE, -1);
}

CMD:boost(playerid, params[])
{
    // Проверим игрока на нахождение в машине.
    if (0 == IsPlayerInVehicle(playerid, boost_veh))
        return SendClientMessage(playerid, -1, "Вы не в гоночной машине!");

    // Рассчитаем скорости машины по осям X и Y с учётом угла, под которым она повёрнута.
    const Float:velocity = 1.5;
    new Float:angle;
    GetVehicleZAngle(boost_veh, angle);
    new Float:vx = velocity * -floatcos(angle - 90.0, degrees);
    new Float:vy = velocity * -floatsin(angle - 90.0, degrees);
    // Придадим машине скорость (получится рывок вперёд).
    return SetVehicleVelocity(boost_veh, vx, vy, 0.0);
}

См. также:

• GetPlayerVehicleSeat
• IsPlayerInAnyVehicle