fclose

Описание:

Закрывает файл, открытый функцией fopen().

Параметры:

(File: handle)

File: handle

Хендл открытого файла. После выполнения данной функции хендл перестаёт быть валидным.

Возвращаемое значение:

true в случае успеха, иначе false.

Баг Pawn

Попытка передать функции неправильный хендл (т.е. не возвращённый функциями fopen() или ftemp(), либо уже закрытый с помощью fclose()) приводит к падению сервера.

Пример использования:

main()
{
    new File:f = fopen("myfile.txt", io_read);

    // Проверим, удалось ли открыть файл.
    if (!f)
    {
        printf("Не удалось открыть файл!");
    }
    else
    {
        new buffer[128];
        new len;
        new linenum = 1;

        // Считываем строки, пока не достигнем конца файла.
        while ((len = fread(f, buffer)) != 0)
        {
            // fread() считывает строку вместе с '\n' на конце - убирём этот знак
            // из конца строки, чтобы не выводить лишний перенос в printf().
            buffer[len-1] = '\0';

            // Выводим номер строки и её содержимое.
            printf("%03d: %s", linenum++, buffer);
        }

        // Не забываем закрыть файл.
        fclose(f);
    }
}

См. также:

• fopen